QManage.txt文本
[@抢庄开始]
#IF
ISONMAP TXDGA
#ACT
SENDMSG 6 [美女服务生]：现在开始抢庄，庄家本钱必须超过1000元宝。
BREAK

[@移动庄家]
#IF
EQUAL A34 <$USERNAME>
EQUAL G12 59
#ACT
MAPMOVE TXDGA 8 10
BREAK

#IF
EQUAL A34 <$USERNAME>
#ACT
MAPMOVE TXDGA 5 11
BREAK

[@抢庄结束]
#IF
ISONMAP TXDGA
#ACT
SENDMSG 6 ┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈
SENDMSG 6 [美女服务生]：抢庄已结束。现在是下注时间，押定离手了。
SENDMSG 6 ┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈
SENDMSG 6 庄家姓名：【<$STR(A34)>】　庄家本钱数：【<$STR(G29)>】
SENDMSG 6 ┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈
BREAK

[@下注开始]
#IF
ISONMAP TXDGA
#ACT
SENDMSG 6 [美女服务生]：现在开始下注了，庄家本钱共有<$STR(G29)>个元宝。
BREAK

[@下注结束]
#IF
ISONMAP TXDGA
LARGE M43 0
#ACT
SENDMSG 7 [提示]：你下注【<$STR(M43)>】元宝押【<$STR(S23)>】
BREAK

[@猜点开始]
#IF
ISONMAP TXDGA
LARGE M43 0
#ACT
MOV D0 <$STR(G42)>
MOV D1 <$STR(G43)>
MOV D2 <$STR(G44)>
PLAYDICE 3 @ZZNEW
#SAY
　\
╔═══════════════╗你所拥有的元宝数：【<$GAMEGOLD>】\
║┏━━━┓┏━━━┓┏━━━┓║\
║┃●　●┃┃●　●┃┃●　●┃║庄家姓名：【<$STR(A34)>】\
║┃●　●┃┃●　●┃┃●　●┃║\
║┃●　●┃┃●　●┃┃●　●┃║庄家本钱数：【<$STR(G29)>】\
║┗━━━┛┗━━━┛┗━━━┛║\
╚═══════════════╝你下注【<$STR(M43)>】元宝押【<$STR(S23)>】\
　\

[@ZZNEW]
#IF
EQUAL G42 <$STR(G43)>
EQUAL G42 <$STR(G44)>
#ACT
SENDMSG 7 [美女服务生]：骰子掷出了【<$STR(G42)>】【<$STR(G43)>】【<$STR(G44)>】点【豹子】
BREAK

#IF
SMALL G45 11
#ACT
SENDMSG 7 [美女服务生]：骰子掷出了【<$STR(G42)>】【<$STR(G43)>】【<$STR(G44)>】点【小】
BREAK

#IF
LARGE G45 10
#ACT
SENDMSG 7 [美女服务生]：骰子掷出了【<$STR(G42)>】【<$STR(G43)>】【<$STR(G44)>】点【大】
BREAK

[@赌博结帐]
#IF
ISONMAP TXDGA
EQUAL A15 豹子
EQUAL A34 <$USERNAME>
#ACT
INC G11 <$STR(G29)>
MOV M44 <$STR(G11)>
DIV M44 0
DEC G11 <$STR(M44)>
INC G47 <$STR(M44)>
GAMEGOLD + <$STR(G11)>
SENDMSG 0 [美女服务生]：庄家【<$USERNAME>】赢得了【<$STR(G11)>】个元宝。
BREAK

#IF
ISONMAP TXDGA
EQUAL A15 大
EQUAL A34 <$USERNAME>
#ACT
INC G29 <$STR(G14)>
DEC G29 <$STR(G13)>
MOV M44 <$STR(G29)>
DIV M44 20
DEC G29 <$STR(M44)>
INC G47 <$STR(M44)>
GAMEGOLD + <$STR(G29)>
SENDMSG 0 [美女服务生]：庄家【<$USERNAME>】收回了【<$STR(G29)>】个元宝。
BREAK

#IF
ISONMAP TXDGA
EQUAL A15 小
EQUAL A34 <$USERNAME>
#ACT
INC G29 <$STR(G13)>
DEC G29 <$STR(G14)>
MOV M44 <$STR(G29)>
DIV M44 20
DEC G29 <$STR(M44)>
INC G47 <$STR(M44)>
GAMEGOLD + <$STR(G29)>
SENDMSG 0 [美女服务生]：庄家【<$USERNAME>】收回了【<$STR(G29)>】个元宝。
BREAK

#IF
ISONMAP TXDGA
EQUAL A15 豹子
LARGE M43 0
#ACT
SENDMSG 6 庄家【<$USERNAME>】掷出了【<$STR(A15)>】，你损失了【<$STR(M43)>】个元宝注金。
MOV M43 0
MOV S23 无
BREAK

#IF
ISONMAP TXDGA
EQUAL A15 大
EQUAL S23 大
#ACT
INC M43 <$STR(M43)>
MOV M44 <$STR(M43)>
DIV M44 20
DEC M43 <$STR(M44)>
INC G47 <$STR(M44)>
GAMEGOLD + <$STR(M43)>
SENDMSG 6 庄家【<$USERNAME>】掷出了【<$STR(A15)>】，你赢得了【<$STR(M43)>】个元宝注金。
MOV M43 0
MOV S23 无
BREAK

#IF
ISONMAP TXDGA
EQUAL A15 小
EQUAL S23 小
#ACT
INC M43 <$STR(M43)>
MOV M44 <$STR(M43)>
DIV M44 20
DEC M43 <$STR(M44)>
INC G47 <$STR(M44)>
GAMEGOLD + <$STR(M43)>
SENDMSG 6 庄家【<$USERNAME>】掷出了【<$STR(A15)>】，你赢得了【<$STR(M43)>】个元宝注金。
MOV M43 0
MOV S23 无
BREAK

#IF
ISONMAP TXDGA
LARGE M43 0
#ACT
SENDMSG 6 庄家【<$USERNAME>】掷出了【<$STR(A15)>】，你损失了【<$STR(M43)>】个元宝注金。

MOV M43 0
MOV S23 无
BREAK

[@赌博清零]
#IF
ISONMAP TXDGA
#ACT
MOV M40 0
MOV M41 0
MOV M42 0
MOV M43 0
MOV M44 0
MOV M45 0
MOV S23 无
BREAK

NPC正文开始：

(@@InPutInteger)
[@MAIN]
欢迎光临，这里是猜点数游戏，你所拥有的元宝：【<$GAMEGOLD>】\
庄家姓名：【<$STR(A34)>】　庄家本钱数：【<$STR(G29)>】\
╔┈┈┈┈╗╔┈┈┈┈╗╔┈┈┈┈╗╔┈┈┈┈╗╔┈┈┈┈╗\
┊<查看说明/@Help>┊┊<开始坐庄/@@InPutInteger40>┊┊<下注押大/@@InPutInteger41>┊┊<下注押小/@@InPutInteger42>┊┊<返回土城/@Over>┊\
╚┈┈┈┈╝╚┈┈┈┈╝╚┈┈┈┈╝╚┈┈┈┈╝╚┈┈┈┈╝\
押大总金额：【<$STR(G13)>】　　　　　　　　　　　剩余时间：<$STR(G8)>\
押小总金额：【<$STR(G14)>】\
你的下注情况：你下注【<$STR(M43)>】元宝押【<$STR(S23)>】　　<刷新/@MAIN>\
<网监提示：猜点数游戏仅供娱乐，禁止进行赌博和违法的金币交易！>\

[@@InPutInteger40]
#If
CheckLevelEx > 0
#Act
DelayGoto 1 ~InPutInteger40
[~InPutInteger40]
#IF
LARGE G12 60
#ACT
MESSAGEBOX [提示]：抢庄时间已经结束。请等待开局！
MOV M40 0
GOTO @MAIN
BREAK

#IF
SMALL M40 1000
#ACT
MESSAGEBOX [提示]：请输入1000以上的数值！
MOV M40 0
GOTO @MAIN
BREAK

#IF
EQUAL A34 <$USERNAME>
#ACT
MOV M40 0
MESSAGEBOX [提示]：你目前已经是庄家，无法重复坐庄。
GOTO @MAIN
BREAK

#IF
EQUAL M45 2
#ACT
MOV M40 0
MESSAGEBOX [提示]：你已经下注押了大，无法坐庄！
GOTO @MAIN
BREAK

#IF
EQUAL M45 3
#ACT
MOV M40 0
MESSAGEBOX [提示]：你已经下注押了小，无法坐庄！
GOTO @MAIN
BREAK

#IF
CHECKGAMEGOLD < <$STR(M40)>
#ACT
MESSAGEBOX [提示]：你身上的元宝不足。
MOV M40 0
GOTO @MAIN
BREAK

#IF
LARGE M40 <$STR(G29)>
#ACT
GMEXECUTE 增加元宝 <$STR(A34)> + <$STR(G29)>
GAMEGOLD - <$STR(M40)>
MOV G29 <$STR(M40)>
SendMSG 4 %s使用<$STR(M40)>个元宝坐庄。
MOV A34 <$USERNAME>
GOTO @MAIN
MESSAGEBOX [提示]：使用【<$STR(M40)>】个元宝坐庄。
BREAK

#ELSEACT
MESSAGEBOX [提示]：你必须出多于【<$STR(G29)>】个元宝才能抢庄。
MOV M40 0
GOTO @MAIN
BREAK

[@@InPutInteger41]
#If
CheckLevelEx > 0
#Act
DelayGoto 1 ~InPutInteger41
[~InPutInteger41]
#IF
LARGE G12 120
#ACT
MESSAGEBOX [提示]：下注时间已经结束。请等待开局！
MOV M41 0
GOTO @MAIN
BREAK

#IF
SMALL G12 61
#ACT
MESSAGEBOX [提示]：下注时间还没到，现在是抢庄时间。
MOV M41 0
GOTO @MAIN
BREAK

#IF
SMALL M41 10
#ACT
MESSAGEBOX [提示]：请输入10以上的数值！
MOV M41 0
GOTO @MAIN
BREAK

#IF
EQUAL A34 <$USERNAME>
#ACT
MOV M40 0
MESSAGEBOX [提示]：你目前已经是庄家，无法重复坐庄。
GOTO @MAIN
BREAK

#IF
EQUAL M45 2
#ACT
MOV M41 0
MESSAGEBOX [提示]：你已经下注押了大，无法重复下注！
GOTO @MAIN
BREAK

#IF
EQUAL M45 3
#ACT
MOV M41 0
MESSAGEBOX [提示]：你已经下注押了小，无法重复下注！
GOTO @MAIN
BREAK

#IF
LARGE M41 <$STR(G9)>
#ACT
MOV M41 0
MESSAGEBOX [提示]：对不起，庄家的本钱已达到上线不够赔了。\　　　　\目前你只可以下注【<$STR(G9)>】以下的元宝！
GOTO @MAIN
BREAK

#IF
CHECKGAMEGOLD > <$STR(M41)>
#ACT
MOV M45 2
MOV S23 大
GAMEGOLD - <$STR(M41)>
MOV M43 <$STR(M41)>
INC G13 <$STR(M43)>
SendMSG 4 %s使用<$STR(M41)>个元宝下注押大。
GOTO @MAIN
MESSAGEBOX [提示]：使用【<$STR(M41)>】个元宝下注押大。
MOV M41 0
BREAK

#ELSEACT
MESSAGEBOX [提示]：你身上的元宝不足。
MOV M41 0
GOTO @MAIN
BREAK

[@@InPutInteger42]
#If
CheckLevelEx > 0
#Act
DelayGoto 1 ~InPutInteger42
[~InPutInteger42]
#IF
LARGE G12 120
#ACT
MESSAGEBOX [提示]：下注时间已经结束。请等待开局！
MOV M42 0
GOTO @MAIN
BREAK

#IF
SMALL G12 61
#ACT
MESSAGEBOX [提示]：下注时间还没到，现在是抢庄时间。
MOV M42 0
GOTO @MAIN
BREAK

#IF
SMALL M42 10
#ACT
MESSAGEBOX [提示]：请输入10以上的数值！
MOV M42 0
GOTO @MAIN
BREAK

#IF
EQUAL A34 <$USERNAME>
#ACT
MOV M40 0
MESSAGEBOX [提示]：你目前已经是庄家，无法重复坐庄。
GOTO @MAIN
BREAK

#IF
EQUAL M45 2
#ACT
MOV M42 0
MESSAGEBOX [提示]：你已经下注押了大，无法重复下注！
GOTO @MAIN
BREAK

#IF
EQUAL M45 3
#ACT
MOV M42 0
MESSAGEBOX [提示]：你已经下注押了小，无法重复下注！
GOTO @MAIN
BREAK

#IF
LARGE M42 <$STR(G10)>
#ACT
MOV M42 0
MESSAGEBOX [提示]：对不起，庄家的本钱已达到上线不够赔了。\　　　　\目前你只可以下注【<$STR(G10)>】以下的元宝！
GOTO @MAIN
BREAK

#IF
CHECKGAMEGOLD > <$STR(M42)>
#ACT
MOV M45 3
MOV S23 小
GAMEGOLD - <$STR(M42)>
MOV M43 <$STR(M42)>
INC G14 <$STR(M43)>
SendMSG 4 %s使用<$STR(M42)>个元宝下注押小。
GOTO @MAIN
MESSAGEBOX [提示]：使用【<$STR(M42)>】个元宝下注押小。
MOV M42 0
BREAK

#ELSEACT
MESSAGEBOX [提示]：你身上的元宝不足。
MOV M42 0
GOTO @MAIN
BREAK

[@Over]
#IF
#ACT
MapMove 3 330 330
BREAK

[@Help]
猜点游戏规则：
1)庄家坐庄后，其他玩家可下注，两分钟后三个骰子随机出现，\
　点数总和小于11代表小，点数总和大于10代表大，三个点数相同\
　代表豹子。
2)押大赢大，押小赢小，豹子通吃，系统每次收取10%税务。\
3)正在坐庄或已下注的玩家如下线将被视做弃权，损失下注元宝。\
4)玩家下注数不能超过庄家坐庄的元宝总和。\
<返回/@MAIN>　　<离开/@EXIT>\

[@IsInFilterList]
#ACT
MESSAGEBOX [错误]：输入数据中包含了非法字符，请重新编辑！

定时器，缺少这个时间不动
[@坐庄游戏A]
#IF
EQUAL G12 0
#ACT
GMEXECUTE 开始提问 @抢庄开始
INC G12 1
BREAK

#IF
EQUAL G12 59
#ACT
GMEXECUTE 开始提问 @移动庄家
INC G12 1
BREAK

#IF
EQUAL G12 60
#ACT
GMEXECUTE 开始提问 @抢庄结束
INC G12 1
BREAK

#IF
EQUAL G12 61
#ACT
GMEXECUTE 开始提问 @下注开始
INC G12 1
BREAK

#IF
EQUAL G12 120
#ACT
GMEXECUTE 开始提问 @下注结束
INC G12 1
BREAK

#IF
EQUAL G12 121
#ACT
MOVR G42 6
inc G42 1
MOVR G43 6
inc G43 1
MOVR G44 6
inc G44 1
MOV G45 <$STR(G42)>
INC G45 <$STR(G43)>
INC G45 <$STR(G44)>
GMEXECUTE 开始提问 @猜点开始
INC G12 1
BREAK

#IF
EQUAL G12 126
#ACT
GMEXECUTE 开始提问 @赌博结帐
INC G12 1
BREAK

#IF
EQUAL G12 128
#ACT
GMEXECUTE 开始提问 @赌博清零
MOV A15 无
MOV G9 0
MOV G10 0
MOV G11 0
MOV G13 0
MOV G14 0
MOV G29 0
MOV G42 0
MOV G43 0
MOV G44 0
MOV G45 0
INC G12 1
BREAK

#IF
EQUAL G12 130
#ACT
GMEXECUTE 开始提问 @移动庄家
MOV A34 无
MOV G12 0
BREAK

#IF
#ACT
INC G12 1
BREAK

[@坐庄游戏B]
#IF
#ACT
MOV G8 130
DEC G8 <$STR(G12)>
MOV G11 <$STR(G13)>
INC G11 <$STR(G14)>
MOV G9 <$STR(G29)>
INC G9 <$STR(G14)>
DEC G9 <$STR(G13)>
MOV G10 <$STR(G29)>
INC G10 <$STR(G13)>
DEC G10 <$STR(G14)>
BREAK

[@坐庄游戏C]
#IF
EQUAL G12 122
EQUAL G42 <$STR(G43)>
EQUAL G42 <$STR(G44)>
#ACT
MOV A15 豹子
BREAK

#IF
SMALL G45 11
#ACT
MOV A15 小
BREAK

#IF
LARGE G45 10
#ACT
MOV A15 大
BREAK
------------------------------------------------------------------
#AutoRun NPC SEC 1 @坐庄游戏A
#AutoRun NPC SEC 1 @坐庄游戏B
#AutoRun NPC SEC 1 @坐庄游戏C

详细设置方法如下：1：首先在D:\Mirserver\Mir200\Envir\MapInfo.txt里边建立这个地图TXDGA代码如下：
[TXDGA|B012 押庄赌场] SAFE NORANDOMMOVE NORECONNECT(0159) NoRecall NoPositionMove NORANDOMMOVE NoGuildRecall NoDearRecall NOMasterRECALL NODRUG NOTALLOWUSEMAGIC(瞬息移动) NOTALLOWUSEITEMS(盟重传送石|比奇传送石|元宝练级卷|超级传送卷)
2：在D:\Mirserver\Mir200\Envir\MerChant.txt里边加上代码：
赌博\庄家        TXDGA        5        14        美女服务员        0        13        0        0        0        0        1
赌博\拉斯维加斯        3        330        330        拉斯维加斯        0        13        0        0        0        0        1
3：在\Mirserver\Mir200\Envir\Market_def\  里边建立文件夹 “赌博”
在赌博里边新建文本文档取名“庄家-txdga.txt”和“拉斯维加斯-3.txt”
4：把上面里的文档的上部分复制到“庄家-txdga.txt”里边  保存
然后在“拉斯维加斯-3.txt”里边写个传送到地图TXDGA的脚本。
5：修改D:\Mirserver\Mir200\Envir\MapQuest_def\QManage.txt

本站声明:本站文章资源均来自网上转载或机器人自动搜索采集,如果本站文章资源有版权问题请联系管理员，我们尽快予以更正。所有文章只限用于个人测试学习使用,不得用于非法商业用途,请勿非法复制传播。特此声明！--[5uwl.net]

五年游戏制作经验; 金牌服务品质保障 游戏开区一条龙 第一品牌无忧网络[5uwl.net]